Create NoveOkno as QForm
    Caption = "Môj program"
    Center
    ShowModal
end create

$typecheck on


dim Okno as QForm
dim Tlacitko as QButton


declare sub Tlacitko_onClick


Okno.Caption = "Program s tlačítkom" ' priradenie nadpisu oknu
Okno.Center ' vycentrovanie okna na stred obrazovky


Tlacitko.Parent = Okno
Tlacitko.Left = 80 ' umiestnenie tlačítka naľavo od kraja
Tlacitko.Top = 50 ' umiestnenie tlačítka hore od kraja
Tlacitko.Width = 150 ' nastavenie šírky tlačítka
Tlacitko.Height = 50 ' nastavenie výšky tlačítka
Tlacitko.Caption = "Koniec programu" ' priradenie názvu tlačítka
Tlacitko.OnClick = Tlacitko_onClick ' zavesenie podprogramu na tlačítko, ktorý sa spustí po kliknutí na tlačítko

Okno.ShowModal ' zobrazenie hlavného okna

' -----------------------
' podprogram, ktorý sa spustí, akonáhle je stlačené tlačítko
' -----------------------

Sub Tlacitko_onClick
    Okno.Close
End Sub

$typecheck on ' zapnutie kontroly syntaxe

declare sub cbxovocie_onchange
declare sub lbxzelenina_onclick

dim frmzoznamy as qform ' hlavné okno (form)
dim lblovocie as qlabel ' textový popis (label) k listboxu
dim cbxovocie as qcombobox ' rozbaľovací zoznam (combobox)
dim lblzelenina as qlabel ' textový popis ku comboboxu
dim lbxzelenina as qlistbox ' roztvorený zoznam (listbox)
dim lblvysledok as qlabel ' popis výsledku (na spodku formulára)

    frmzoznamy.caption = "ukážka zoznamov"
    frmzoznamy.width = 180
    frmzoznamy.height = 280
    frmzoznamy.center
    frmzoznamy.delbordericons 1, 2

    lblovocie.parent = frmzoznamy
    lblovocie.left = 10
    lblovocie.top = 10
    lblovocie.caption = "ukážka comboboxu"

    cbxovocie.parent = frmzoznamy
    cbxovocie.left = 10
    cbxovocie.top = 30
    cbxovocie.width = 150
    cbxovocie.style = 2 ' hodnota 2 zabezpečí, že sa do zoznamu nedá písať
    cbxovocie.additems "čerešňa", "marhuľa", "hruška", "jablko" ' naplnenie zoznamu
    cbxovocie.onchange = cbxovocie_onchange ' udalosť po zmene položky spustí podprogram

' nastavenie labelu (popisu) lblzelenina
' ----------------------------------
    lblzelenina.parent = frmzoznamy
    lblzelenina.left = 10
    lblzelenina.top = 65
    lblzelenina.caption = "ukážka listboxu"

with lbxzelenina
    .parent = frmzoznamy
    .left = 10
    .top = 80
    .width = 150
    .height = 110
    .additems "cibuľa", "mrkva", "kaleráb", "hrach", "fazuľa"' naplnenie zoznamu položkami
    .onclick = lbxzelenina_onclick' udalosť po kliknutí na položku zoznamu
    .color = rgb(&hcc, &hff, &h00)' žltá farba listboxu (t.j. pozadia)
    .font.color = rgb(&h00, &h00, &hcc) ' modrá farba písma
    .font.size = 12 ' veľkosť písma
    .font.name = "courier new" ' názov písma
    .font.addstyles 0 ' 0 = tučné písmo, 1 = šikmé písmo, 2 = podčiarknuté
end with

with lblvysledok
    .parent = frmzoznamy
    .left = 10: .top = 200
    .caption = "čakám na kliknutie do zoznamu" + chr$(10) + chr$(13) + "potom sa môj text zmení"
    .font.color = rgb(&hcc, &h00, &h00) ' červená farba písma
end with

frmzoznamy.showmodal ' zobrazenie hlavného okna

' ----------------------------------
sub cbxovocie_onchange
    lblvysledok.caption = "vybrané ovocie: " + cbxovocie.item(cbxovocie.itemindex)
end sub

sub lbxzelenina_onclick
    lblvysledok.caption = "poradie položky: " + _
         str$(lbxzelenina.itemindex) + chr$(10) + chr$(13) + _
         "vybraná zelenina: " + lbxzelenina.item(lbxzelenina.itemindex) end sub

' začiatok kódu
$typecheck on ' zapnutie kontroly syntaxe

' deklarácia komponent
dim frmprogram as qform ' hlavné okno
dim redprogram as qrichedit ' textové pole
dim mnuprogram as qmainmenu ' hlavné menu
dim mnusubor as qmenuitem ' prvé podmenu
dim mnuotvorit as qmenuitem ' druhé podmenu
dim mnupauza as qmenuitem ' druhé podmenu
dim mnukoniec as qmenuitem ' druhé podmenu

' deklarácia podprogramov
declare sub mnuotvorit_onclick ' ak užívateľ stlačí menu otvoriť
declare sub mnukoniec_onclick ' ak užívateľ stlačí menu koniec
declare sub frmprogram_onclose (action as integer) ' pri zatvorení hlavného okna

' vlastnosti okna
with frmprogram
    .caption = "ukážka práce s menu"
    .center
    .onclose = frmprogram_onclose
end with

' vlastnosti textového poľa
with redprogram
    .parent = frmprogram
    .font.name = "courier new"
    .align = 5 ' (zarovnanie 5 = na celú plochu rodiča - viď rapidq.inc pre ostatné zarovnania)
end with

' hlavné menu
mnuprogram.parent = frmprogram
mnuprogram.additems mnusubor

' prvé podmenu
mnusubor.caption = "&súbor"
mnusubor.additems mnuotvorit, mnupauza, mnukoniec

' druhé podmenu
with mnuotvorit
    .caption = "&otvoriť" ' nadpis
    .shortcut = "ctrl+o" ' klávesová skratka
    .onclick = mnuotvorit_onclick ' udalosť pri spustení
end with

mnupauza.caption = "-" ' oddeľovač menu má nadpis "-"

with mnukoniec
    .caption = "&koniec"
    .shortcut = "esc"
    .onclick = mnukoniec_onclick
end with

frmprogram.showmodal

' -----------------------------
sub mnuotvorit_onclick
    dim opendialog as qopendialog ' komponent pre otvorenie súboru
    opendialog.initialdir = curdir$ ' nastavenie súčasného (aktuálneho) adresára pri otvorení
    opendialog.filter = "textový súbor (*.txt)|*.txt" ' filter zabezpečí zobrazenie len textových súborov. spustí sa otváracie okno, kde užívateľ môže vybrať ľubovoľný súbor.
    ' ak je textový súbor vybraný
    if opendialog.execute then
        ' jeho obsah sa načíta do textového poľa redprogram
        redprogram.loadfromfile (opendialog.filename)
    end if
end sub

' -----------------------------
sub mnukoniec_onclick
    ' ukončenie programu
    frmprogram.close
end sub

' -----------------------------
sub frmprogram_onclose
' keď sa zatvára hlavné okno, užívateľ má možnosť ešte ovlpyvniť uzatvorenie. ak odpovie na otázku "ukončiť program?" tlačítkom ok, program sa ukončí. ak odpovie cancel (= storno), okno sa nezavrie (cez premennú action = 0)
    if messagebox ("ukončiť program?", "pozor!", 1) <> 1 then action = 0
end sub

' začiatok kódu
$typecheck on ' zapnutie kontroly syntaxe

$Resource ico_file as "file.ico" ' zahrnutie obrázku ikony do programu

' ------------------------ deklarácia ovládacích prvkov (komponent)
    dim frmPriklad as QForm
    dim lviPriklad as QListView
    dim lblPriklad as QLabel
    dim cbxPriklad as QComboBox
    dim dirPriklad as QDirTree
    dim ImageList1 as QImageList
    dim ImageList2 as QImageList

' -------------------------- deklarácia podprogramov
    declare sub dirPriklad_onChange
    declare sub cbxPriklad_onChange

' -------------------------- vlastnosti použitých komponent
with frmPriklad
    .caption = "Kúzla s QListView"
    .width = 640
    .height = 480
    .center
    .onshow = dirPriklad_onChange
end with

with lblPriklad
    .parent = frmPriklad
    .left = 410
    .top = 10
    .caption = "Zobraziť súbory ako:"
end with

with cbxPriklad
    .parent = frmPriklad
    .left = 520
    .width = 100
    .top = 7
    .style = 2
    .addItems "veľké ikony", "malé ikony", "zoznam", "tabuľka"
    .itemIndex = 3 ' 4. položka zoznamu (číslovanie od 0 do 3)
    .onChange = cbxPriklad_onChange
end with

with lviPriklad
    .parent = frmPriklad
    .width = 400
    .align = 3 ' zarovnanie automaticky vľavo na formulár
    .viewstyle = 3 ' 3 = vsReport (typu Zoznam alebo tabuľka)
    .addcolumns "Súbor", "Veľkosť", "Dátum", "Čas" ' stĺpce pri ViewStyle = 3
    .column(0).width = 160 ' šírka 1. stĺpca
    .column(1).width = 80 ' šírka 2. stĺpca
    .column(2).width = 70 ' šírka 3. stĺpca
    .column(3).width = 50 ' šírka 4. stĺpca
    .gridlines = 1 ' true
    .rowselect = 1 ' true
    .LargeImages = ImageList1 ' použitie ikony súboru (32 x 32 pixelov)
    .SmallImages = ImageList2 ' použitie ikony súboru (16 x 16 pixelov)
end with

with ImageList1
    .Height = 32
    .Width = 32
    .AddICOHandle ico_file
End With

with ImageList2
    .Height = 15
    .Width = 15
    .AddICOHandle ico_file
End With

with dirPriklad
    .parent = frmPriklad
    .left = 410
    .top = 40
    .width = 210
    .height = 390
    .directory = "C:\"
    .onChange = dirPriklad_onChange
end with

frmPriklad.ShowModal

' --------------------------
Sub cbxPriklad_onChange
    ' zmena pohľadu QListView (viď RapidQ.INC pre štýly)
    lviPriklad.ViewStyle = cbxPriklad.ItemIndex
End Sub

' --------------------------
Sub dirPriklad_onChange
    dim subor as String
    ' deklarácia premennej SUBOR (pre načítanie textu)
    lviPriklad.Clear ' vymazanie obsahu lviPriklad
    ' načítanie všetkých súborov
    subor = Dir$(dirPriklad.directory + "*.*", 0)
    while subor <> "" ' pokiaľ je názov súboru načítaný (t. j. nie je prázdny text)
        lviPriklad.AddItems FileRec.FileName ' pridanie položky do zoznamu
        lviPriklad.AddSubItem (lviPriklad.ItemCount - 1, Str$(FileRec.Size))         ' pridanie podpoložky Veľkosť
        lviPriklad.AddSubItem (lviPriklad.ItemCount - 1, FileRec.Date) ' pridanie podpoložky Dátum
        lviPriklad.AddSubItem (lviPriklad.ItemCount - 1, FileRec.Time) ' pridanie podpoložky Čas
        subor = Dir$ ' Načítanie ďalšieho súboru v poradí
    wend
End Sub

' KONIEC KÓDU

' začiatok kódu
$typecheck on ' zapnutie kontroly syntaxe

' deklarácia podprogramu, ktorých opravuje minimalizáciu okna
declare Function SetWindowLong LIB "User32" ALIAS "SetWindowLongA" _
    (hwnd AS Long, nIndex AS Long, dwNewLong AS Long) AS LONG

' deklarácia podprogramov okna
    declare sub frmHlavny_onShow
    declare sub frmHlavny_onClose (Action as Integer)
    declare sub frmHlavny_onPaint
    declare sub frmHlavny_onMouseMove (X as Integer, Y as Integer, Shift as Integer)

' použité komponenty (v tomto príklade iba dva!)
    dim frmHlavny as QForm, stbHlavny as QStatusBar

with stbHlavny
    .parent = frmHlavny
    .sizegrip = 0 ' zabránenie zmene veľkosti stavového riadku
    .addpanels " Toto je stavový riadok ", "Pozícia kurzora myši:", "" ' rozdelenie na tri panely
    .panel(0).width = 230
    .panel(1).width = 230
end with

' nastavenie základných vlastností, metód a udalostí okna (viď prílohu A, časť QForm)
with frmHlavny
    .width = 640 ' šírka okna
    .height = 480 ' výška okna
    .delbordericons 2 ' zneprístupnenie maximalizačného tlačítka
    ' pozri RapidQ.INC pre ďalšie nastavenia QForm (časť Border Icons)
    .borderstyle = 1 ' jednoduchý okraj bez možnosti zmeny veľkosti okna
    ' pozri RapidQ.INC pre ďalšie nastavenia QForm (časť Border Styles)
    .cursor = -21 ' kurzor myši v tvare ruky
    ' pozri RapidQ.INC pre ďalšie nastavenia kurzoru (časť CURSORS Variables)
    .caption = "Ukážka práce s formulárom" ' nadpis okna
    .color = rgb(&H99, &H33, &H33) ' farba pozadia
    .font.name = "Courier New" ' názov písma na formulári
    .font.size = 10 ' veľkosť písma na formulári
    .font.addstyles 0 ' vytučnenie písma (zrušiť sa dá príkazom DelStyles 0)
    ' pozri RapidQ.INC pre ďalšie nastavenia písma QFont (časť QFONT Variables)
    .hint = "Toto je bublinková nápoveda formulára" ' text bublinkovej nápovedy
    .showHint = 1 ' povolenie zobrazenia bublinkovej nápovedy

' udalosti okna
    .onShow = frmHlavny_onShow ' udalosť, ktorá sa spustí tesne pred zobrazením okna
    .onClose = frmHlavny_onClose ' udalosť, ktorá sa spustí tesne pred zatvorením okna
    .onPaint = frmHlavny_onPaint ' udalosť, ktorá sa spustí pri prekreslení okna
    .onMouseMove = frmHlavny_onMouseMove ' udalosť, ktorá sa spustí pri kliknutí na okno

' metódy okna
    .center ' vycentrovanie okna je odporúčané uvádzať vždy po určení výšky a šírky okna
    SetWindowLong frmHlavny.handle, -8, 0 ' použitie opravy minimalizácie okna
    SetWindowLong application.handle, -8, .handle ' musí byť na konci vlastností okna
    .showmodal ' zobrazenie okna
end with

' ------------------------
Sub frmHlavny_onShow
    ' môžete pridávať ľubovoľný kód pred spustením hlavného formulára, napr. zistenie veľkosti obrazovky
    frmHlavny.Caption = frmHlavny.Caption + " - rozlíšenie obrazovky " + _
    str$(screen.width) + " x " + str$(screen.height) + " pixelov."
    ' šírka a výška obrazovky je vrátená v tvare čísla (integer), ktoré je potrebné ešte previesť na textový reťazec, aby mohlo byť zobrazené. prevod zabezpečuje funkcia str$(číslo), v našom prípade str$(screen.width)
End Sub

' ------------------------
Sub frmHlavny_onClose
    dim temp as byte
    ' funkcia MessageBox zobrazí dialógové okno s textom a tlačítkami (viď prílohu C, časť "Ďalšie detailné kľúčové slová", heslo MessageBox) &H4 = YESNO tlačítka, &H20 = ICONQUESTION (obrázok otáznika)
    temp = MessageBox ("Chcete zatvoriť okno?", "VÝZVA", &H4 + &H20)
    If temp <> 6 then Action = 0
End Sub

' ------------------------
Sub frmHlavny_onPaint
    ' vykreslenie štvoruholníka v okne
    frmHlavny.Rectangle (200, 100, 250, 200, rgb(&HFF, &HFF, &HFF))
    ' vypísanie textu do okna
    frmHlavny.TextOut (40, 80, "Rapid-Q ?", rgb(&HFF, &HFF, &HFF), -1)
    frmHlavny.TextOut (70, 220, "Rapid-Q !", rgb(&HFF, &HFF, &H00), -1)
    ' vykreslenie kruhu s výplňou čiernou (ak chcete prázdnu, dajte -1 namiesto 0)
    frmHlavny.Circle (150, 250, 400, 400, rgb(&HFF, &HFF, &H00), 0)
    ' vykreslenie štvoruholníka so zaoblenými rohmi
    frmHlavny.RoundRect (480, 50, 600, 350, 10, 10, rgb(&HFF, &HCC, &H00))
End Sub

' ------------------------
Sub frmHlavny_onMouseMove
    dim X as integer, Y as integer
    frmHlavny.PSet(X, Y, rgb(&HFF, &HFF, &H00)) ' metóda PSet na kreslenie v okne
    stbHlavny.panel(2).Caption = " X = " + str$(X) + ", Y = " + str$(Y)     ' zobrazenie koordinátov kurzoru myši v status bare (opäť sú integer X a integer Y prevedené na stringy - textové reťazce)
End Sub

' KONIEC KÓDU

' začiatok kódu
$typecheck on ' zapnutie kontroly syntaxe

    Application.Title = "Hlavolam"
    $option icon "ikona.ico"
    const crlf = chr$(13) + chr$(10)

' ----------------------------------
' Komponenty a udalosti
' ----------------------------------

    Dim I as byte
    Dim frmEnigma as QForm
    Dim btnEnigma(0 to 8) as QCoolBtn
    Dim mnuEnigma as QMainMenu
    Dim MnuEnigmaProgram as QMenuItem
    Dim mnuZnova as QMenuItem
    Dim mnuPravidla as QMenuItem
    Dim mnuRiesenie as QMenuItem
    Dim mnuEnigmaPauza1 as QMenuItem
    Dim mnuOEnigme as QMenuItem
    Dim mnuEnigmaPauza2 as QMenuItem
    Dim mnuEnigmaKoniec as QMenuItem

    Declare sub btnEnigma_onClick (Sender as QCoolBtn)
    Declare Sub frmEnigma_OnShow
    Declare Sub Controll
    Declare Sub mnuZnovu_OnClick
    Declare Sub mnuPravidla_OnClick
    Declare Sub mnuRiesenie_OnClick
    Declare Sub mnuOEnigme_OnClick
    Declare Sub mnuEnigmaKoniec_OnClick

' ------------------------------
' Components
' ------------------------------

With frmEnigma
    .Caption = "Hlavolam / Enigma"
    .Width = 375: .Height = 100
    .BorderStyle = 1 ' pevný
    .DelBorderIcons 1, 2
    .Color = rgb(&H00, &H00, &HFF)
    .OnShow = frmEnigma_OnShow
    .Center
End With

For I = 0 to 8
    btnEnigma(I).Parent = frmEnigma
    btnEnigma(I).Top = 4
    btnEnigma(I).width = 40
    btnEnigma(I).Height = 40
    btnEnigma(I).Left = 5 + (I * 40)
    btnEnigma(I).Flat = 1
    btnEnigma(I).OnClick = btnEnigma_onClick
    btnEnigma(I).Font.Name = "Wingdings"
    btnEnigma(I).Font.Size = 40
    btnEnigma(I).Font.AddStyles 0
Next I

' ------------------------------
' Menu
' ------------------------------

    mnuEnigma.Parent = frmEnigma
    mnuEnigma.AddItems MnuEnigmaProgram
    MnuEnigmaProgram.Caption = "Program"
    MnuEnigmaProgram.AddItems mnuZnova, mnuPravidla, mnuRiesenie, mnuEnigmaPauza1, _
    mnuOEnigme, mnuEnigmaPauza2, mnuEnigmaKoniec

with mnuZnova
    .Caption = "&Znova"
    .ShortCut = "F5"
    .OnClick = mnuZnovu_OnClick
end With

with mnuPravidla
    .Caption = "&Pravidlá"
    .ShortCut = "F6"
    .OnClick = mnuPravidla_OnClick
end With

with mnuRiesenie
    .Caption = "&Riešenie"
    .ShortCut = "F7"
    .OnClick = mnuRiesenie_OnClick
end With

mnuEnigmaPauza1.caption = "-"

with mnuOEnigme
    .Caption = "&O programe"
    .ShortCut = "F8"
    .OnClick = mnuOEnigme_OnClick
end With

mnuEnigmaPauza2.caption = "-"

with mnuEnigmaKoniec
    .Caption = "&Koniec / Exit"
    .ShortCut = "Esc"
    .OnClick = mnuEnigmaKoniec_OnClick
end With

frmEnigma.ShowModal

' -------------------------
' Subs
' -------------------------
Sub frmEnigma_OnShow
    For I = 0 to 8
        btnEnigma(I).Hint = Str$(I)
        btnEnigma(I).Caption = "l"
        btnEnigma(I).Visible = 1
        If I < 4 then
            btnEnigma(I).Tag = 1 ' Tag 1 = zlta gula
            btnEnigma(I).Font.Color = rgb(&HFF, &HFF, &H00)
        End If
        If I > 4 then
            btnEnigma(I).Tag = 2 ' Tag 2 = cervena gula
            btnEnigma(I).Font.Color = rgb(&HCC, &H00, &H33)
        End If
    Next

    btnEnigma(4).Tag = 0 ' Tag 0 = ziadna gula
    btnEnigma(4).Visible = 0
End Sub ' -----------------------------

Sub btnEnigma_onClick
    Select Case Sender.Tag
    Case 1 ' Ak je zlta gula
        Select Case Sender.Hint
        Case "7"
        If btnEnigma(Val(Sender.Hint) + 1).Tag = 0 then
            Sender.Tag = 0
            Sender.Visible = 0
            btnEnigma(Val(Sender.Hint) + 1).Visible = 1
            btnEnigma(Val(Sender.Hint) + 1).Tag = 1
            btnEnigma(Val(Sender.Hint) + 1).Font.Color = rgb(&HFF, &HFF, &H00)
        End If

        Case < 7 ' od 0 do 6
            If btnEnigma(Val(Sender.Hint) + 1).Tag = 0 then
                Sender.Tag = 0
                Sender.Visible = 0
                btnEnigma(Val(Sender.Hint) + 1).Visible = 1
                btnEnigma(Val(Sender.Hint) + 1).Tag = 1
                btnEnigma(Val(Sender.Hint) + 1).Font.Color = rgb(&HFF, &HFF, &H00)
            ElseIf btnEnigma(Val(Sender.Hint) + 1).Tag = 2 and btnEnigma(Val(Sender.Hint) + 2).Tag = 0 then
                Sender.Tag = 0
                Sender.Visible = 0
                btnEnigma(Val(Sender.Hint) + 2).Visible = 1
                btnEnigma(Val(Sender.Hint) + 2).Tag = 1
                btnEnigma(Val(Sender.Hint) + 2).Font.Color = rgb(&HFF, &HFF, &H00)
            End If
End Select

    Case 2 ' Ak je červena gula
    Select Case Sender.Hint
        Case "0"
            If btnEnigma(Val(Sender.Hint) - 1).Tag = 0 then
                Sender.Tag = 0
                Sender.Visible = 0
                btnEnigma(Val(Sender.Hint) - 1).Visible = 1
                btnEnigma(Val(Sender.Hint) - 1).Tag = 2
                btnEnigma(Val(Sender.Hint) - 1).Font.Color = rgb(&HCC, &H00, &H33)
            End If
        Case Else ' od 0 do 6
            If btnEnigma(Val(Sender.Hint) - 1).Tag = 0 then
                Sender.Tag = 0
                Sender.Visible = 0
                btnEnigma(Val(Sender.Hint) - 1).Visible = 1
                btnEnigma(Val(Sender.Hint) - 1).Tag = 2
                btnEnigma(Val(Sender.Hint) - 1).Font.Color = rgb(&HCC, &H00, &H33)
            ElseIf btnEnigma(Val(Sender.Hint) - 1).Tag = 1 and btnEnigma(Val(Sender.Hint) - 2).Tag = 0 then
                Sender.Tag = 0
                Sender.Visible = 0
                btnEnigma(Val(Sender.Hint) - 2).Visible = 1
                btnEnigma(Val(Sender.Hint) - 2).Tag = 2
                btnEnigma(Val(Sender.Hint) - 2).Font.Color = rgb(&HCC, &H00, &H33)
            End If
       End Select
   End Select
   Controll
End Sub

' ---------------------------------
Sub Controll
    Dim Temp as Byte
    Temp = 0
    For I = 0 to 3
        If btnEnigma(I).Tag <> 2 then Temp++
    Next

    If btnEnigma(4).Tag <> 0 then Temp++

For I = 5 to 8
        If btnEnigma(I).Tag <> 1 then Temp++
    Next

    If Temp = 0 then ShowMessage "Gratulujem! Úloha je vyriešená!"
End sub

' ---------------------------------
Sub mnuZnovu_OnClick
    If MessageDlg ("Odznova ?", 3, 1 or 2, 0) = 7 then Exit Sub
    frmEnigma_OnShow
End Sub

' ---------------------------------
Sub mnuPravidla_OnClick
    ShowMessage "Cieľom hlavolamu je vymeniť pozície žltých a červených gulí. Žlté gule sa pohybujú len smerom doprava, červené len doľava. Guľa môže prejsť na vedľajšie voľné pole, alebo preskočiť guľu opačnej farby, ak je hneď za ňou voľné pole. Krok späť nie je možný, preto celý hlavolam je potrebné riešiť odznovu."
End Sub

' ---------------------------------
Sub mnuRiesenie_OnClick
    If MessageDlg ("Určite chcete vedieť riešenie?", 3, 1 or 2, 0) = 7 then Exit Sub
    ShowMessage "Sú dve riešenia - podľa toho, či prvá ťahá žltá (Ž) alebo červená (Č)." + crlf + _
"Ak Ž, riešenie je nasledovné:" + crlf + _
"Ž - ČČ - ŽŽŽ - ČČČČ - ŽŽŽŽ - ČČČČ - ŽŽŽ - ČČ - Ž" + crlf + _
"Ak Č guľa ťahá prvá, riešenie je také isté, len farby sú prehodené..."
    End Sub

' ---------------------------------
Sub mnuEnigmaKoniec_OnClick
    frmEnigma.Close
End Sub

' ---------------------------------
Sub mnuOEnigme_OnClick
    ShowMessage "Program: Hlavolam" + Chr$(13) + _
    "Verzia: 1.0 (freeware)" + Chr$(13) + Chr$(13) + _
    "Autor: Slavomir Svetlik" + Chr$(13) + _
    "(c) august 2004"
End Sub

' KONIEC KÓDU